|
|
一个万能脚本，可以套用其他条件或者材料，来进行装备属性升级。可指定属性点数，也可以随机获得点数。
----------部分节选------,方法照抄就行
[@main-1]
#SAY
你想要升级哪个部位的装备？请根据身上侗装备选择。\
每次升级需要消耗<一件>相同装备，要先佩带装备。\
会根据升级次数和等级<收取元宝>！<请先查看相应装备详情>!\
┏━━━┳━━━┳━━━┳━━━┳━━━┳━━━┳━━━┓\
┃<盔 甲/@升盔甲0>┃<武 器/@升武器1>┃<项 链/@升项链3>┃<头 盔/@升头盔4>┃ ┃\
┃<右手镯/@升右手镯5>┃<左手镯/@升左手镯6>┃<右戒指/@升右戒指7>┃<左戒指/@升左戒指8>┃ ┃\
┃<勋 章/@升勋章9>┃<腰 带/@升腰带10>┃<鞋 子/@升鞋子11>┃<宝 石/@升宝石12>┃ ┃\
┃当前升级次数限<最高十星>！更高星级等待开发！ <取 消/@取消6>┃\
┗━━━┻━━━┻━━━┻━━━┻━━━┻━━━┻━━━┛\
[@盔甲详情]
#SAY
<升级消耗元宝和一相同装备，请注意本条，损失不补。>\
衣服武器5星以下收10万元宝加4点。5星及以上收20万元宝加3点。\
防御、魔御5星以下加3点，5星以上加2点!!\
同步可能放开装备数量 限制！\
━━━━━━━━━━━━━━━━━━━━━━━━━━<返 回/@升盔甲0>\
[@升盔甲0]
#IF
CheckUseItem 0
#SAY
<武器升级><请先看详情/@升级规则>!\
请选择升级的属性！<请注意选择升级属性！><武器升级详情/@武器详情>\
请选择升级的属性,<请注意选择升级属性和详情/@盔甲详情>！\
━━━━━━━━━━━━━━━━━━━━━━━━━━━━━\
<0 防御5/@盔甲属性0>┃<1 魔御5/@盔甲属性1>┃<2 攻击5/@盔甲属性2>┃ \
<3 魔法5/@盔甲属性3>┃<4 道术5/@盔甲属性4>┃\
━━━━━━━━━━━━━━━━━━━━━━━━━━<返 回/@main-1>
#ELSESAY
请先佩带需要升级的装备。
[@盔甲属性0]
#IF
#ACT
;设置赋值属性代码变量，赋值给<$STR(S300)>，0是防御
MOV S300 0
;设置5星以下收取元宝数量 10万
MOV S400 100000
;设置5星以上收取元宝数量 20万
MOV S500 200000
;升级5星以下升级加点数为3
MOV S600 3
;升级5星以上升级加点数为2
MOV S700 2
;赋值装备位置为一个变量，以为引用，作为通用变量，赋值给变量<$STR(S200)>，是为了减少代码行数。
MOV S200 0
;检查衣服位置0装备的物品名称 位置(0-51) S变量(0-999))，赋值给变量<$STR(S100)>，是为了检查人物背包有没这个装备，根据升级条件来设置。
;此处是因为要消耗相同的装备来升级,如果是升级宝石，这时可以设置需要的数量，原理一样。
GetUserItemName 0 100
goto @升级装备
[@升级装备]
#IF
;查检背包指定名称物品的数量是否足够，引用前面赋值的变量
CHECKITEM <$STR(S100)> 1
;检查元宝数量是否足够升级装备
CheckGameGold > <$STR(S400)>
;检查升级次数,方式=0时检测正在升级的装备（OK框）,方式=1时检测人物身上的装备..
;CheckItemupgradeCount 方式(0,1) 位置(0-51) 操作符(> = <) 次数(0-255)
CheckItemupgradeCount 1 <$STR(S200)> < 5
#ACT
;调整装备升级次数或星星数量,ChangeItemUpgradeCount 物品位置(0~51,-1时为OK框物品) 操作符(+,-,=) 星星数量次数(0~255)
;因为是必定能够升级成功，所以可以先设置升级星级
ChangeItemUpgradeCount <$STR(S200)> + 1
;回收需要的升级的材料或者冲击力，并收取前面设定的元宝数量
TAKE <$STR(S100)> 1
GameGold - <$STR(S400)>
;有机率调整装备属性，UPGRADEITEMEX 物品位置(0-51) 属性位置(0-14) 成功机率(0-100) 点数机率(0-255) 是否破碎(0,1)
;有机率调整5点对应属性，必成功，不碎
;成功机率不能为100，否则无效
;UPGRADEITEMEX <$STR(S200)> <$STR(S300)> 99 5 0
;-------------------------------
;固定调整身上装备属性
;CHANGEITEMADDVALUE 装备位置(-1时是OK框中的装备, 0-12时是穿在身上的装备) 属性位置(0-14) (符号 + - =) 值
;硬性加对应位置的属性点，引用前面设定的变量，套用这段执行脚本
CHANGEITEMADDVALUE <$STR(S200)> <$STR(S300)> + <$STR(S600)>
;消息提醒 一下
SENDMSG 6 你的《 <$STR(S100)> 》已经升级成功！！！！！！！
;重新给变量赋值，防止内存溢出导致数据添加错误（如果连续狂点，可能会出现这种情况）,可能与服务器响应时间设置有关。
MOV S300 0
MOV S400 0
MOV S500 0
MOV S600 0
MOV S700 0
MOV S200 0
Break
#IF
CHECKITEM <$STR(S100)> 1
;检查元宝数量
CheckGameGold > <$STR(S500)>
CheckItemupgradeCount 1 <$STR(S200)> < 10
#ACT
ChangeItemUpgradeCount <$STR(S200)> + 1
TAKE <$STR(S100)> 1
GameGold - <$STR(S500)>
;UPGRADEITEMEX <$STR(S200)> <$STR(S300)> 99 5 0
CHANGEITEMADDVALUE <$STR(S200)> <$STR(S300)> + <$STR(S700)>
SENDMSG 6 你的《 <$STR(S100)> 》已经升级成功！！！！！！！
MOV S300 0
MOV S400 0
MOV S500 0
MOV S600 0
MOV S700 0
MOV S200 0
Break
#IF
CHECKITEM <$STR(S100)> 0
#SAY
请检查升级的装备数量是否足够！\
━━━━━━━━━━━━━━━━━━━━━━━<取 消/@取消6>\
#IF
CheckItemupgradeCount 1 <$STR(S200)> = 10
#SAY
!\
一件装备最多只能升级十次！\
━━━━━━━━━━━━━━━━━━━━━━━<取 消/@取消6>\
#IF
CheckGameGold < <$STR(S400)>
#SAY
?\
?\
检查是否有足够元宝作为备用金！\
━━━━━━━━━━━━━━━━━━━━━━━<取 消/@取消6>\
|
|
发表于 2023-5-4 21:14:52
楼主